本篇文章给大家分享的是有关怎么在易语言中通过post操作的小米路由器，小编觉得挺实用的，因此分享给大家学习，希望大家阅读完这篇文章后可以有所收获，话不多说，跟着小编一起来看看吧。

操作小米路由器的代码

此功能需要加载精易模块5.6

.版本 2
.支持库 iext2
.程序集 窗口程序集_启动窗口
.程序集变量 IP, 文本型
.程序集变量 cookie, 文本型
.程序集变量 token, 文本型
.子程序 登录, 文本型
.参数 密码, 文本型
.参数 返回内容, 文本型, 参考
.参数 token, 文本型, 参考
.局部变量 临时, 文本型
.局部变量 deviceId, 文本型
.局部变量 key, 文本型
.局部变量 时间戳, 文本型
.局部变量 随机数, 文本型
.局部变量 psw, 文本型
.局部变量 nonce, 文本型
.局部变量 密码加密, 文本型
.局部变量 nonce编码, 文本型
临时 ＝ 网页_访问S (“http://” ＋ IP ＋ “/cgi-bin/luci/web”)
deviceId ＝ 文本_取出中间文本 (临时, “deviceId = '”, “'”)
key ＝ 文本_取出中间文本 (临时, “key: '”, “'”)
时间戳 ＝ 时间_到时间戳 (, 真)
随机数 ＝ 文本_取随机范围数字 (1000, 9999)
psw ＝ 密码
nonce ＝ “0_” ＋ deviceId ＋ “_” ＋ 时间戳 ＋ “_” ＋ 随机数
密码加密 ＝ 校验_取sha1 (到字节集 (nonce ＋ 校验_取sha1 (到字节集 (psw ＋ key))))
增加日志 (“key:” ＋ #换行符 ＋ key)
增加日志 (“nonce:” ＋ #换行符 ＋ nonce)
增加日志 (“nonce编码:” ＋ #换行符 ＋ nonce编码)
返回内容 ＝ 网页_访问S (“http://” ＋ IP ＋ “/cgi-bin/luci/api/xqsystem/login”, 1, “username=admin&password=” ＋ 密码加密 ＋ “&logtype=2&nonce=” ＋ nonce, , cookie, , , 真)
token ＝ 文本_取出中间文本 (返回内容, “token” ＋ #引号 ＋ “:” ＋ #引号, #引号)
.如果真 (寻找文本 (返回内容, #引号 ＋ “code” ＋ #引号 ＋ “:0”, , 假) ＝ -1)
  返回 (“失败”)
.如果真结束
返回 (“成功”)
.子程序 增加日志
.参数 日志内容, 文本型
日志编辑框.加入文本 (日志内容 ＋ #换行符 ＋ “------------------------------------------------------------------------” ＋ #换行符)
.子程序 _登陆按钮_被单击
.局部变量 返回, 文本型
.局部变量 返回内容, 文本型
.局部变量 psw, 文本型
IP ＝ IP编辑框.地址
psw ＝ 密码编辑框.内容
token ＝ “”
.如果真 (IP ＝ “” 或 psw ＝ “”)
  信息框 (“IP或密码不能为空”, 0, )
  返回 ()
.如果真结束
返回 ＝ 登录 (psw, 返回内容, token)
.判断开始 (返回 ＝ “成功”)
  增加日志 (“登陆成功:” ＋ #换行符 ＋ 返回内容)
  增加日志 (“token:” ＋ #换行符 ＋ token)
.默认
  增加日志 (“登录失败:” ＋ #换行符 ＋ 返回内容)
.判断结束
.子程序 _断开按钮_被单击
.局部变量 返回, 文本型
.如果真 (token ＝ “”)
  信息框 (“请先登录”, 0, )
  返回 ()
.如果真结束
返回 ＝ 网页_访问S (“http://” ＋ IP ＋ “/cgi-bin/luci/;stok=” ＋ token ＋ “/api/xqnetwork/pppoe_stop”)
.判断开始 (寻找文本 (返回, #引号 ＋ “code” ＋ #引号 ＋ “:0”, , 假) ＝ -1)
  增加日志 (“断网失败:” ＋ #换行符 ＋ 返回)
.默认
  增加日志 (“断网成功:” ＋ #换行符 ＋ 返回)
.判断结束
.子程序 _拨号按钮_被单击
.局部变量 返回, 文本型
.如果真 (token ＝ “”)
  信息框 (“请先登录”, 0, )
  返回 ()
.如果真结束
返回 ＝ 网页_访问S (“http://” ＋ IP ＋ “/cgi-bin/luci/;stok=” ＋ token ＋ “/api/xqnetwork/pppoe_start”)
.判断开始 (寻找文本 (返回, #引号 ＋ “code” ＋ #引号 ＋ “:0”, , 假) ＝ -1)
  增加日志 (“拨号失败:” ＋ #换行符 ＋ 返回)
.默认
  增加日志 (“拨号成功:” ＋ #换行符 ＋ 返回)
.判断结束

运行结果：

以上就是怎么在易语言中通过post操作的小米路由器，小编相信有部分知识点可能是我们日常工作会见到或用到的。希望你能通过这篇文章学到更多知识。更多详情敬请关注天达云行业资讯频道。